Zero-length stream copies within one component instance trap for non-numeric payloads #753

;; With a write pending on a `stream<string>`, a zero-length read from the
;; same component instance copies nothing and returns COMPLETED(0).
(component
  (core module $libc
    (memory (export "memory") 1)
    (func (export "realloc") (param i32 i32 i32 i32) (result i32) unreachable))
  (core instance $libc (instantiate $libc))
  (type $stream (stream string))
  (core func $stream.new (canon stream.new $stream))
  (core func $stream.read (canon stream.read $stream async
    (memory (core memory $libc "memory")) (realloc (core func $libc "realloc"))))
  (core func $stream.write (canon stream.write $stream async
    (memory (core memory $libc "memory"))))
  (core module $m
    (import "" "stream.new" (func $stream.new (result i64)))
    (import "" "stream.read" (func $stream.read (param i32 i32 i32) (result i32)))
    (import "" "stream.write" (func $stream.write (param i32 i32 i32) (result i32)))
    (func (export "run") (result i32)
      (local $pair i64)
      (local.set $pair (call $stream.new))
      (if (i32.ne (i32.const -1) ;; BLOCKED
            (call $stream.write
              (i32.wrap_i64 (i64.shr_u (local.get $pair) (i64.const 32)))
              (i32.const 0) (i32.const 1)))
        (then unreachable))
      (call $stream.read (i32.wrap_i64 (local.get $pair)) (i32.const 0) (i32.const 0)))
  )
  (core instance $i (instantiate $m (with "" (instance
    (export "stream.new" (func $stream.new))
    (export "stream.read" (func $stream.read))
    (export "stream.write" (func $stream.write))))))
  (func (export "run") async (result u32) (canon lift (core func $i "run")))
)


(assert_return (invoke "run") (u32.const 0)) ;; COMPLETED(0)